; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
#define MyAppName "立思辰扫描软件"
#define MyAppVersion "4.37.14100.23004"
#define MyAppSetupName "LanxumScan_App_Setup"
#define MyAppDefSetupDir "LanxumScan"
#define MyAppPublisher "立思辰信息科技有限公司"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{F2890F43-A51C-4379-BB79-992616B1D6BD}
AppName={#MyAppName}
AppVerName={#MyAppName}
AppVersion={#MyAppVersion}
DefaultDirName={pf}\{#MyAppDefSetupDir}
DefaultGroupName={#MyAppName}
VersionInfoVersion={#MyAppVersion}
OutputDir=..\..\package
OutputBaseFilename={#MyAppSetupName}_{#MyAppVersion}
Compression=lzma
AppPublisher={#MyAppPublisher}
SolidCompression=no
UninstallIconFile=uninstall.ico
SetupIconFile=LanxumScan_App.ico
LicenseFile=LanxumScan_App_License.txt
AlwaysShowComponentsList=true
ArchitecturesInstallIn64BitMode=x64
PrivilegesRequired=admin
DisableWelcomePage=no

[Languages]
Name: "zn"; MessagesFile: "compiler:Languages/ChineseSimp.isl" 

[Components]
Name: "Upgrade"; Description: "在线升级功能" ; Types: Full
Name: "TwainG42S"; Description: "LANXUMSCAN G42S TWAIN" ; Types: Full
Name: "TwainG52S"; Description: "LANXUMSCAN G52S TWAIN" ; Types: Full
Name: "TwainG62S"; Description: "LANXUMSCAN G62S TWAIN" ; Types: Full
Name: "TwainG73S"; Description: "LANXUMSCAN G73S TWAIN" ; Types: Full                    

[Files]

; app
Source: ".\LanxumScan_App.ico"; DestDir: "{app}\"; Flags: ignoreversion
Source: "..\..\..\..\code_app\doc\scanner\LanxumScan_App_Help_manual.pdf"; DestDir: "{app}\"; Flags: ignoreversion
Source: "..\..\..\..\code_app\doc\scanner\LanxumScan_scanSettings_Help_manual.pdf"; DestDir: "{app}\"; Flags: ignoreversion

; app32
Source: "..\..\x86\Qt\iconengines\*"; DestDir: "{app}\iconengines\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\tessdata\*"; DestDir: "{app}\tessdata\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\imageformats\*"; DestDir: "{app}\imageformats\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\platforms\*"; DestDir: "{app}\platforms\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\styles\*"; DestDir: "{app}\styles\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\translations\*"; DestDir: "{app}\translations\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Qt\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LanxumScan.exe"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LSCUpgradeApp.exe"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LSCBase.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LSCImgFmt.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LSCImgProc.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\LSCVersion.dll"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\libmupdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\pdflib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\msvcp140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\vcruntime140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\Release\concrt140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\sane.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\scanner.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\lang.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{app}\lang\"; Flags: ignoreversion; Check: not Is64BitInstallMode

; app64
Source: "..\..\x64\Qt\iconengines\*"; DestDir: "{app}\iconengines\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\tessdata\*"; DestDir: "{app}\tessdata\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\imageformats\*"; DestDir: "{app}\imageformats\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\platforms\*"; DestDir: "{app}\platforms\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\styles\*"; DestDir: "{app}\styles\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\translations\*"; DestDir: "{app}\translations\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Qt\*.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LanxumScan.exe"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LSCUpgradeApp.exe"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LSCBase.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LSCImgFmt.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LSCImgProc.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\LSCVersion.dll"; DestDir: "{app}\"; Flags: ignoreversion;  Components: Upgrade; Check: Is64BitInstallMode
Source: "..\..\x64\Release\libmupdf.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\pdflib.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\msvcp140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\vcruntime140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\vcruntime140_1.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\Release\concrt140.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\sane.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\scanner.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\lang.dll"; DestDir: "{app}\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{app}\lang\"; Flags: ignoreversion; Check: Is64BitInstallMode

; twain32
Source: "..\..\..\..\code_app\doc\scanner\LanxumScan_scanSettings_Help_manual.pdf"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\msvcp140.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\vcruntime140.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\concrt140.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\sane.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\scanner.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\lang.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\..\lang\*"; DestDir: "{win}\twain_32\LanxumTwain\lang\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\LSCBase.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\LSCImgFmt.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\LSCImgProc.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\LSCVersion.dll"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\Release\tessdata\*"; DestDir: "{win}\twain_32\LanxumTwain\tessdata\"; Flags: ignoreversion; Check: Is64BitInstallMode
Source: "..\..\x86\OEM\lanxum\lanxumtwain8420.ds"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG42S;
Source: "..\..\x86\OEM\lanxum\lanxumtwain8520.ds"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG52S;
Source: "..\..\x86\OEM\lanxum\lanxumtwain8620.ds"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG62S;
Source: "..\..\x86\OEM\lanxum\lanxumtwain8730.ds"; DestDir: "{win}\twain_32\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG73S;

; twain64
Source: "..\..\x64\OEM\lanxum\lanxumtwain8420.ds"; DestDir: "{win}\twain_64\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG42S;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\lanxumtwain8520.ds"; DestDir: "{win}\twain_64\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG52S;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\lanxumtwain8620.ds"; DestDir: "{win}\twain_64\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG62S;  Check: Is64BitInstallMode
Source: "..\..\x64\OEM\lanxum\lanxumtwain8730.ds"; DestDir: "{win}\twain_64\LanxumTwain\"; Flags: ignoreversion;  Components: TwainG73S;  Check: Is64BitInstallMode

;拷贝驱动
Source: "..\..\usb\lanxum\lanxumusb.inf"; DestDir: "{app}\driver\";  Flags: ignoreversion recursesubdirs;
Source: "..\..\usb\lanxum\lanxumusb.cat"; DestDir: "{app}\driver\";  Flags: ignoreversion recursesubdirs;
Source: "..\..\x86\Release\DPInst32.exe"; DestDir: "{app}\";  Flags: ignoreversion recursesubdirs;  Check: not IsWin64
Source: "..\..\x64\Release\DPInst64.exe"; DestDir: "{app}\";  Flags: ignoreversion recursesubdirs;  Check: IsWin64

; 临时使用
Source: "..\..\x86\Release\LSCRemoveOldApp.exe"; DestDir: "{tmp}\";  Flags: ignoreversion
Source: "..\..\x86\Release\LSCCheckNewApp.exe"; DestDir: "{app}\";  Flags: ignoreversion; Check: not Is64BitInstallMode
Source: "..\..\x64\Release\LSCCheckNewApp.exe"; DestDir: "{app}\";  Flags: ignoreversion; Check: Is64BitInstallMode

[INI]

[Icons]
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\LanxumScan.exe"
Name: "{group}\{#MyAppName}"; Filename: "{app}\LanxumScan.exe"
Name: "{group}\立思辰扫描软件帮助文档"; Filename: "{app}\LanxumScan_App_Help_manual.pdf"
Name: "{group}\卸载"; Filename: "{uninstallexe}";

[Registry]
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "AppDirectory"; ValueData: "{app}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "Application"; ValueData: "{app}\LanxumScan.exe"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "AppVersion"; ValueData: "{#MyAppVersion}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: not Is64BitInstallMode
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{win}\twain_32\LanxumTwain"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\LanxumScan"; ValueType: string; ValueName: "DriverPath64"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\WOW6432Node\LanxumScan"; ValueType: string; ValueName: "DriverPath"; ValueData: "{win}\twain_32\LanxumTwain"; Flags: uninsdeletekey;  Check: Is64BitInstallMode
Root: HKLM; Subkey: "Software\WOW6432Node\LanxumScan"; ValueType: string; ValueName: "DriverPath64"; ValueData: "{app}"; Flags: uninsdeletekey;  Check: Is64BitInstallMode

[Code]

var 
  globalInstallPath: String;
 
//初始化时把路径设置到编辑框
procedure InitializeWizard;
begin
  WizardForm.DirEdit.Text := globalInstallPath;
end;

function GetInstallString(): String;
var
  InstallPath: String;
begin
  InstallPath := ExpandConstant('{pf}\{#MyAppDefSetupDir}');
  if RegValueExists(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{F2890F43-A51C-4379-BB79-992616B1D6BD}_is1', 'Inno Setup: App Path') then
    begin
      RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{F2890F43-A51C-4379-BB79-992616B1D6BD}_is1', 'Inno Setup: App Path', InstallPath)
    end
  result := InstallPath;
end;

function InitializeSetup(): boolean;
var
  ErrorCode: Integer;
  ResultCode: Integer;
  ResultStr: String;
  UninstallContinue: Boolean;
  CmdStr: String;
begin
  Result := false;
  globalInstallPath := GetInstallString();
  CmdStr := GetCmdTail();
  ExtractTemporaryFile('LSCRemoveOldApp.exe');
  if Exec(ExpandConstant('{tmp}\LSCRemoveOldApp.exe'), '', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode) then
  begin
    if 0 = ErrorCode then
    begin
      if RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{F2890F43-A51C-4379-BB79-992616B1D6BD}_is1', 'UninstallString', ResultStr) then
      begin
        UninstallContinue := true;
        if Pos('/verysilent', CmdStr) = 0 then
        begin
          if MsgBox('扫描软件已安装，是否卸载原版本？', mbConfirmation, MB_YESNO) <> IDYES then
          begin
            UninstallContinue := false;
          end
        end
        if UninstallContinue then
        begin
          ResultStr := RemoveQuotes(ResultStr);  
          if Exec(ResultStr, '/verysilent', '', SW_HIDE, ewWaitUntilTerminated, ResultCode) then
          begin
            if 0 = ResultCode then
            begin
              Sleep(1000)
              Result := true;
            end
          end
        end
      end
      else
      begin
        Result := true;
      end
    end
    else if 2 = ErrorCode then
    begin
      MsgBox('请先关闭旧版扫描软件！', mbInformation, MB_OK);
    end
    else
    begin
      MsgBox('卸载旧版扫描软件失败，停止安装！', mbInformation, MB_OK);
    end 
  end
end;

function SetUninstallIcon(iconPath:string): Boolean;
var
  InstalledVersion,SubKeyName: String;
begin
  SubKeyName :=  'Software\Microsoft\Windows\CurrentVersion\Uninstall\{F2890F43-A51C-4379-BB79-992616B1D6BD}_is1';
  RegWriteStringValue(HKLM,SubKeyName,'DisplayIcon',iconPath);
end;

function InitializeUninstall(): Boolean;
var
  ErrorCode: Integer;
begin
  Result := false;
  if Exec(ExpandConstant('{app}\LSCCheckNewApp.exe'), '', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode) then
  begin
    if 0 = ErrorCode then
    begin
      ShellExec('', ExpandConstant('{app}\LSCUpgradeApp.exe'), '-type=postuninstallinfo -appName=Scanner -desc=uninstall', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
      Result := true;
    end
    else
    begin
      MsgBox('请先关闭扫描软件！', mbInformation, MB_OK);
    end
  end
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then
  begin
    SetUninstallIcon(ExpandConstant('{app}\LanxumScan_App.ico'));
    DeleteFile(ExpandConstant('{win}\twain_32\LanxumTwain\lanxumtwain8200.ds'));
    DeleteFile(ExpandConstant('{win}\twain_32\LanxumTwain\lanxumtwain8429.ds'));
    DeleteFile(ExpandConstant('{win}\twain_32\LanxumTwain\lanxumtwain8529.ds'));
    DeleteFile(ExpandConstant('{win}\twain_32\LanxumTwain\lanxumtwain8629.ds'));
    DeleteFile(ExpandConstant('{win}\twain_32\LanxumTwain\lanxumtwain8739.ds'));
    DeleteFile(ExpandConstant('{win}\twain_64\LanxumTwain\lanxumtwain8200.ds'));
    DeleteFile(ExpandConstant('{win}\twain_64\LanxumTwain\lanxumtwain8429.ds'));
    DeleteFile(ExpandConstant('{win}\twain_64\LanxumTwain\lanxumtwain8529.ds'));
    DeleteFile(ExpandConstant('{win}\twain_64\LanxumTwain\lanxumtwain8629.ds'));
    DeleteFile(ExpandConstant('{win}\twain_64\LanxumTwain\lanxumtwain8739.ds'));
    DelTree(ExpandConstant('{win}\twain_32\LanxumTwain\x86'), True, True, True);
    DelTree(ExpandConstant('{win}\twain_32\LanxumTwain\x64'), True, True, True);
  end;
end;

procedure CurUninstallStepChanged(CurUninstallStep:TUninstallStep);
begin
  if CurUninstallStep = usDone then
  begin
    DelTree(ExpandConstant('{app}'), True, True, True);
    DelTree(ExpandConstant('{win}\twain_32\LanxumTwain'), True, True, True);
    DelTree(ExpandConstant('{win}\twain_64\LanxumTwain'), True, True, True);
  end;
 end;

[Run]
Filename: "{app}\DPInst32"; Parameters: "/path ""{app}\driver"" /sw /se /lm /f"; Check: not IsWin64; Flags: runascurrentuser
Filename: "{app}\DPInst64"; Parameters: "/path ""{app}\driver"" /sw /se /lm /f"; Check: IsWin64; Flags: runascurrentuser
Filename: "{app}\LSCUpgradeApp.exe"; Parameters:"-type=postinstallinfo -appName=Scanner -desc=install/upgrade";  Components: Upgrade; Flags: runascurrentuser
Filename: "{app}\LanxumScan.exe"; Description: "{cm:LaunchProgram, {#MyAppName}}"; Flags: postinstall nowait skipifsilent runascurrentuser

[UninstallRun]
; 卸载驱动
;Filename: "{app}\DPInst32"; Parameters: "/u ""{app}\driver\lanxumusb.inf"" /q /d"; Check: not IsWin64; Flags: runascurrentuser
;Filename: "{app}\DPInst64"; Parameters: "/u ""{app}\driver\lanxumusb.inf"" /q /d"; Check: IsWin64; Flags: runascurrentuser