#-------------------------------------------------
#
# Project created by QtCreator 2019-08-06T11:56:42
#
#-------------------------------------------------

QT += core

TARGET = gdev
TEMPLATE = lib

CONFIG += c++11

SOURCES += \
    GScan.cpp \
    GScanO200.cpp \
    ImageMatQueue.cpp \
    ImageMultiOutput.cpp \
    PaperSize.cpp \
    scn_config.cpp \


HEADERS += \
    BlockingQueue.h \
    GScan.h \
    GScanO200.h \
    IConfig.h \
    IUsb.h \
    ImageMatQueue.h \
    ImageMultiOutput.h \
    PaperSize.h \
    device_common.h \
    filetools.h \
    scn_config.h

DEFINES += GDEV_LIBRARY GIMGPROC_LIBRARY
DEFINES += QT_NO_VERSION_TAGGING


INCLUDEPATH +=  $$PWD/../ImageProcess $$PWD/../Tirdparty/3rdparty/nick
DEPENDPATH +=  $$PWD/../ImageProcess $$PWD/../Tirdparty/3rdparty/nick

win32{
    DEFINES += _WIN32
    SOURCES += UsbScanEx.cpp
    HEADERS += UsbScanEx.h

    INCLUDEPATH += $$PWD/../Tirdparty/3rdparty/win/libusb/include \
                   $$PWD/../Tirdparty/3rdparty/win/cyusb/include \
                   $$PWD/../Tirdparty/3rdparty/win/opencv/include

    DEPENDPATH += $$PWD/../Tirdparty/3rdparty/win/libusb/include \
                  $$PWD/../Tirdparty/3rdparty/win/cyusb/include \
                  $$PWD/../Tirdparty/win/opencv/include

    LIBS += -L$$PWD/../Tirdparty/3rdparty/win/opencv/x86/lib \
            -L$$PWD/../Tirdparty/3rdparty/win/cyusb/lib/x86 -lCyAPI \
            -L$$PWD/../Tirdparty/3rdparty/win/libusb/MS32/static -llibusb-1.0 \

#-llegacy_stdio_definitions -luser32
    CONFIG(release, debug|release){
         DESTDIR += ../bin/x86/release
         LIBS += -lopencv_world346
         LIBS += -L$$PWD/../bin/x86/release -lgimgproc
    }
    CONFIG(debug, debug|release){
        DESTDIR += ../bin/x86/debug
        LIBS += -lopencv_world346d
        LIBS += -L$$PWD/../bin/x86/debug -lgimgproc
    }

}

else:unix:!macx: {
    SOURCES += libusbex.cpp
    HEADERS += libusbex.h

    LIBS += -lopencv_core -lopencv_highgui -lopencv_imgproc -lopencv_imgcodecs  -lusb-1.0
    CONFIG(release, debug|release){
            DESTDIR += ../bin/x86/release
            LIBS += -L$$PWD/../bin/x86/release -lgimgproc
    }
    CONFIG(debug, debug|release){
            DESTDIR += ../bin/x86/debug
            LIBS += -L$$PWD/../bin/x86/debug -lgimgproc
    }
}
#VERSION = 1.0.0.0
QMAKE_TARGET_PRODUCT = "gdev"
QMAKE_TARGET_COMPANY = "huagaoscan"
QMAKE_TARGET_DESCRIPTION = "文件描述"
QMAKE_TARGET_COPYRIGHT = "版权"